qt 6.5.1 original

cmake/QtBuildInternals/QtStandaloneTestTemplateProject/CMakeLists.txt

@@ -0,0 +1,34 @@
+# Copyright (C) 2022 The Qt Company Ltd.
+# SPDX-License-Identifier: BSD-3-Clause
+
+cmake_minimum_required(VERSION 3.16)
+project(qt_single_test VERSION 6.0.0 LANGUAGES C CXX ASM)
+
+find_package(Qt6 REQUIRED COMPONENTS BuildInternals Core)
+
+include(${CMAKE_CURRENT_LIST_DIR}/Main.cmake NO_POLICY_SCOPE)
+
+# Get the absolute path of the passed-in project dir, relative to the current working directory
+# of the calling script, rather than relative to this source directory.
+# The calling script sets PWD. If not set, just use the passed-in value as-is.
+if(DEFINED PWD)
+    get_filename_component(absolute_project_path "${QT_STANDALONE_TEST_PATH}" ABSOLUTE
+                           BASE_DIR "${PWD}")
+else()
+    set(absolute_project_path "${QT_STANDALONE_TEST_PATH}")
+endif()
+
+# If path does not include the drive letter, we try to add it.
+get_filename_component(absolute_project_path "." REALPATH BASE_DIR "${absolute_project_path}")
+
+if(NOT IS_DIRECTORY "${absolute_project_path}")
+    get_filename_component(filename "${absolute_project_path}" NAME)
+    get_filename_component(directory "${absolute_project_path}" DIRECTORY)
+
+    if(filename STREQUAL "CMakeLists.txt")
+        set(absolute_project_path "${directory}")
+    endif()
+endif()
+
+# Add the test project path as a subdirectory project.
+add_subdirectory("${absolute_project_path}" "build_dir")

cmake/QtBuildInternals/QtStandaloneTestTemplateProject/Main.cmake

@@ -0,0 +1,26 @@
+# Copyright (C) 2022 The Qt Company Ltd.
+# SPDX-License-Identifier: BSD-3-Clause
+
+# Includes QtSetup and friends for private CMake API.
+qt_internal_project_setup()
+qt_build_internals_set_up_private_api()
+
+# Find all StandaloneTestsConfig.cmake files, and include them
+# This will find all Qt packages that are required for standalone tests.
+# It will find more packages that needed for a certain test, but will ensure any test can
+# be built.
+qt_get_standalone_tests_config_files_path(standalone_tests_config_path)
+
+file(GLOB config_files "${standalone_tests_config_path}/*")
+foreach(file ${config_files})
+    include("${file}")
+endforeach()
+
+# Set language standards after finding Core, because that's when the relevant
+# feature variables are available.
+qt_set_language_standards()
+
+# Just before adding the test, change the local (non-cache) install prefix to something other than
+# the Qt install prefix, so that tests don't try to install and pollute the Qt install prefix.
+# Needs to be called after qt_get_standalone_tests_confg_files_path().
+qt_set_up_fake_standalone_tests_install_prefix()