qt 6.5.1 original

mkspecs/devices/linux-rasp-pi-g++/qmake.conf

@@ -0,0 +1,52 @@
+# qmake configuration for:
+#  - Raspberry PI
+#  - Raspberry PI Zero
+# http://wiki.qt.io/RaspberryPi
+
+include(../common/linux_device_pre.conf)
+
+QMAKE_RPATHLINKDIR_POST += $$[QT_SYSROOT]/opt/vc/lib
+
+QMAKE_LIBDIR_OPENGL_ES2 = $$[QT_SYSROOT]/opt/vc/lib
+QMAKE_LIBDIR_EGL        = $$QMAKE_LIBDIR_OPENGL_ES2
+QMAKE_LIBDIR_OPENVG     = $$QMAKE_LIBDIR_OPENGL_ES2
+
+QMAKE_INCDIR_EGL        = $$[QT_SYSROOT]/opt/vc/include \
+                          $$[QT_SYSROOT]/opt/vc/include/interface/vcos/pthreads \
+                          $$[QT_SYSROOT]/opt/vc/include/interface/vmcs_host/linux
+QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}
+QMAKE_INCDIR_OPENVG     = $${QMAKE_INCDIR_EGL}
+
+QMAKE_LIBS_EGL          = -lEGL -lGLESv2
+QMAKE_LIBS_OPENVG       = -lEGL -lOpenVG -lGLESv2
+
+QMAKE_INCDIR_BCM_HOST   = $$[QT_SYSROOT]/opt/vc/include
+QMAKE_LIBDIR_BCM_HOST   = $$[QT_SYSROOT]/opt/vc/lib
+QMAKE_LIBS_BCM_HOST     = -lbcm_host
+
+contains(DISTRO, squeeze) {
+    #Debian Squeeze: Legacy everything
+    QMAKE_LIBS_OPENGL_ES2   = -lGLESv2 -lEGL
+} else:contains(DISTRO, arch) {
+    #On principle: no wizardry required
+} else {
+    #This is not strictly necessary
+    DISTRO_OPTS += deb-multi-arch
+    DISTRO_OPTS += hard-float
+}
+
+QMAKE_CFLAGS           += \
+                          -marm \
+                          -mfpu=vfp \
+                          -mtune=arm1176jzf-s \
+                          -march=armv6zk \
+                          -mabi=aapcs-linux
+
+QMAKE_CXXFLAGS          = $$QMAKE_CFLAGS
+
+# Preferred eglfs backend
+EGLFS_DEVICE_INTEGRATION = eglfs_brcm
+
+include(../common/linux_arm_device_post.conf)
+
+load(qt_config)

mkspecs/devices/linux-rasp-pi-g++/qplatformdefs.h

@@ -0,0 +1,4 @@
+// Copyright (C) 2016 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+#include "../../linux-g++/qplatformdefs.h"