qt 6.5.1 original

mkspecs/devices/linux-rasp-pi3-g++/qmake.conf

@@ -0,0 +1,48 @@
+# qmake configuration for the Raspberry Pi 3 using the Broadcom graphics stack
+
+include(../common/linux_device_pre.conf)
+
+# For modern Yocto-based sysroots that have the proper include and lib
+# setup in egl.pc we will pull the necessary arguments from
+# there. However, to support Raspbian and older stuff that has /opt/vc
+# and possibly no pkg-config, have some static values as well:
+
+# I consider it a bug that this is required, but our EGL config.test _requires_ it
+QMAKE_RPATHLINKDIR_POST += $$[QT_SYSROOT]/opt/vc/lib
+
+VC_LIBRARY_PATH         = /opt/vc/lib
+VC_INCLUDE_PATH         = =/opt/vc/include
+
+VC_LINK_LINE            = -L=$${VC_LIBRARY_PATH}
+
+QMAKE_LIBDIR_OPENGL_ES2 = =$${VC_LIBRARY_PATH}
+QMAKE_LIBDIR_EGL        = $$QMAKE_LIBDIR_OPENGL_ES2
+QMAKE_LIBDIR_OPENVG     = $$QMAKE_LIBDIR_OPENGL_ES2
+
+QMAKE_INCDIR_EGL        = \
+                        $${VC_INCLUDE_PATH} \
+                        $${VC_INCLUDE_PATH}/interface/vcos/pthreads \
+                        $${VC_INCLUDE_PATH}/interface/vmcs_host/linux
+
+QMAKE_INCDIR_OPENGL_ES2 = $${QMAKE_INCDIR_EGL}
+
+QMAKE_LIBS_OPENGL_ES2   = $${VC_LINK_LINE} -lGLESv2
+
+# The official opt vc EGL references GLESv2 symbols: need to link it
+QMAKE_LIBS_EGL          = $${VC_LINK_LINE} -lEGL -lGLESv2
+
+QMAKE_LIBDIR_BCM_HOST   = =$$VC_LIBRARY_PATH
+QMAKE_INCDIR_BCM_HOST   = $$VC_INCLUDE_PATH
+QMAKE_LIBS_BCM_HOST     = -lbcm_host
+
+QMAKE_CFLAGS            = -march=armv8-a -mtune=cortex-a53 -mfpu=crypto-neon-fp-armv8
+QMAKE_CXXFLAGS          = $$QMAKE_CFLAGS
+
+DISTRO_OPTS            += hard-float
+DISTRO_OPTS            += deb-multi-arch
+
+EGLFS_DEVICE_INTEGRATION= eglfs_brcm
+
+include(../common/linux_arm_device_post.conf)
+
+load(qt_config)

mkspecs/devices/linux-rasp-pi3-g++/qplatformdefs.h

@@ -0,0 +1,4 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
+
+#include "../../linux-g++/qplatformdefs.h"