amass/qt6windows7
1
0
Fork 0
mirror of https://github.com/crystalidea/qt6windows7.git synced 2025-07-06 09:15:23 +08:00
Code Issues Actions Packages Projects Releases Wiki Activity

qt 6.5.1 original

Browse Source
This commit is contained in:
kleuter
2023-10-29 23:33:08 +01:00
parent 71d22ab6b0
commit 85d238dfda
21202 changed files with 5499099 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

6
mkspecs/features/unix/bsymbolic_functions.prf Normal file
View File

@ -0,0 +1,6 @@
dll {
QMAKE_LFLAGS_SHLIB += $$QMAKE_LFLAGS_BSYMBOLIC_FUNC
!isEmpty(QMAKE_DYNAMIC_LIST_FILE):QMAKE_LFLAGS_SHLIB += $$QMAKE_LFLAGS_DYNAMIC_LIST$$QMAKE_DYNAMIC_LIST_FILE
}

19
mkspecs/features/unix/ccache.prf Normal file
View File

@ -0,0 +1,19 @@
macx-xcode: return()
darwin: load(sdk)
ccache_prefix = ccache
precompile_header {
CCACHE_SLOPPINESS += pch_defines time_macros
ccache_prefix = \
CCACHE_SLOPPINESS=\"$$join(CCACHE_SLOPPINESS, ',')\$${CCACHE_SLOPPINESS+,\$$CCACHE_SLOPPINESS}\" \
# Make sure we build sources directly, not from their preprocessed version,
# otherwise precompiled headers will not be used during cache misses.
CCACHE_CPP2=true \
$$ccache_prefix
}
for(tool, $$list(QMAKE_CC QMAKE_CXX QMAKE_LINK QMAKE_LINK_SHLIB QMAKE_LINK_C)): \
$$tool = $$ccache_prefix $$eval($$tool)

3
mkspecs/features/unix/hide_symbols.prf Normal file
View File

@ -0,0 +1,3 @@
QMAKE_CFLAGS += $$QMAKE_CFLAGS_HIDESYMS
QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_HIDESYMS
QMAKE_LFLAGS += $$QMAKE_LFLAGS_HIDESYMS

2
mkspecs/features/unix/largefile.prf Normal file
View File

@ -0,0 +1,2 @@
DEFINES += _LARGEFILE64_SOURCE _LARGEFILE_SOURCE

7
mkspecs/features/unix/no_direct_extern_access.prf Normal file
View File

@ -0,0 +1,7 @@
clang {
QMAKE_CFLAGS += -fno-direct-access-external-data
QMAKE_CXXFLAGS += -fno-direct-access-external-data
} else {
QMAKE_CFLAGS += -mno-direct-extern-access
QMAKE_CXXFLAGS += -mno-direct-extern-access
}

12
mkspecs/features/unix/opengl.prf Normal file
View File

@ -0,0 +1,12 @@
qtConfig(opengles2) {
INCLUDEPATH += $$QMAKE_INCDIR_OPENGL_ES2
!isEmpty(QMAKE_LIBDIR_OPENGL_ES2):QMAKE_LIBDIR += $$QMAKE_LIBDIR_OPENGL_ES2
target_qt:LIBS_PRIVATE += $$QMAKE_LIBS_OPENGL_ES2
else:LIBS += $$QMAKE_LIBS_OPENGL_ES2
} else {
INCLUDEPATH += $$QMAKE_INCDIR_OPENGL
!isEmpty(QMAKE_LIBDIR_OPENGL):QMAKE_LIBDIR += $$QMAKE_LIBDIR_OPENGL
target_qt:LIBS_PRIVATE += $$QMAKE_LIBS_OPENGL
else:LIBS += $$QMAKE_LIBS_OPENGL
}

111
mkspecs/features/unix/separate_debug_info.prf Normal file
View File

@ -0,0 +1,111 @@
have_target:!static:if(darwin|!isEmpty(QMAKE_OBJCOPY)) {
darwin {
debug_info_copy_bin = $$QMAKE_DSYMUTIL
debug_info_strip_bin = $$QMAKE_STRIP
debug_info_suffix = dSYM
debug_info_out = --flat -o
debug_info_strip = -S
} else {
debug_info_copy_bin = $$QMAKE_OBJCOPY
debug_info_strip_bin = $$QMAKE_OBJCOPY
qnx {
debug_info_suffix = sym
debug_info_keep = --keep-file-symbols
debug_info_strip = --strip-debug -R.ident
} else {
debug_info_suffix = debug
debug_info_keep = --only-keep-debug
debug_info_strip = --strip-debug
}
}
load(resolve_target)
debug_info_target = $$QMAKE_RESOLVED_TARGET
darwin {
!isEmpty(QMAKE_RESOLVED_BUNDLE) {
debug_info_target = $$QMAKE_RESOLVED_BUNDLE
CONFIG += any_bundle
}
debug_info_target_rel = $$section(debug_info_target, /, -1, -1)
debug_info_target_dir_suffix = .$$debug_info_suffix/Contents/Resources/DWARF
debug_info_target_dir = $${debug_info_target}$${debug_info_target_dir_suffix}
debug_info_target_dir_rel = $${debug_info_target_rel}$${debug_info_target_dir_suffix}
!isEmpty(QMAKE_RESOLVED_BUNDLE): \
QMAKE_TARGET_DEBUG_INFO = $$debug_info_target_dir/$$TARGET
else: \
QMAKE_TARGET_DEBUG_INFO = $$debug_info_target_dir/$$section(QMAKE_RESOLVED_TARGET, /, -1, -1)
if(any_bundle:!build_pass)|if(!any_bundle:if(build_pass|isEmpty(BUILDS))) {
equals(TEMPLATE, lib):lib_bundle:!isEmpty(QMAKE_FRAMEWORK_BUNDLE_NAME): \
BUNDLEIDENTIFIER = $$replace(QMAKE_FRAMEWORK_BUNDLE_NAME, \\.framework$, )
else: equals(TEMPLATE, app):app_bundle:!isEmpty(QMAKE_APPLICATION_BUNDLE_NAME): \
BUNDLEIDENTIFIER = $$replace(QMAKE_APPLICATION_BUNDLE_NAME, \\.app$, )
else: \
BUNDLEIDENTIFIER = $${TARGET}
!isEmpty(QMAKE_TARGET_BUNDLE_PREFIX): \
BUNDLEIDENTIFIER = $$replace(QMAKE_TARGET_BUNDLE_PREFIX, \\.$, ).$${BUNDLEIDENTIFIER}
else: \
BUNDLEIDENTIFIER = com.yourcompany.$${BUNDLEIDENTIFIER}
BUNDLEIDENTIFIER ~= s,_,-,
debug_info_plist.input = $$QMAKESPEC/Info.plist.dSYM.in
debug_info_plist.output = $${debug_info_target}.$$debug_info_suffix/Contents/Info.plist
QMAKE_SUBSTITUTES += debug_info_plist
!isEmpty(QMAKE_DSYM_DEBUG_SCRIPT) {
debug_script.input = $$QMAKE_DSYM_DEBUG_SCRIPT
debug_script.output = $${debug_info_target}.$$debug_info_suffix/Contents/Resources/Python/$${TARGET}.py
debug_script.CONFIG = verbatim
QMAKE_SUBSTITUTES += debug_script
}
}
contains(INSTALLS, target):isEmpty(target.files):isEmpty(target.commands):isEmpty(target.extra) {
!build_pass|release {
debug_info_plist_target.CONFIG += no_check_exist
debug_info_plist_target.files = $${debug_info_target}.$$debug_info_suffix/Contents/Info.plist
debug_info_plist_target.path += $${target.path}/$${debug_info_target_rel}.$$debug_info_suffix/Contents
INSTALLS += debug_info_plist_target
!isEmpty(debug_script.output) {
debug_script_target.CONFIG += no_check_exist
debug_script_target.files = $${debug_script.output}
debug_script_target.path += $${target.path}/$${debug_info_target_rel}.$$debug_info_suffix/Contents/Resources/Python
INSTALLS += debug_script_target
}
}
debug_info_target.CONFIG += no_check_exist
debug_info_target.files = $$QMAKE_TARGET_DEBUG_INFO
debug_info_target.path += $${target.path}/$${debug_info_target_dir_rel}
INSTALLS += debug_info_target
}
} else {
QMAKE_TARGET_DEBUG_INFO = $${QMAKE_RESOLVED_TARGET}.$$debug_info_suffix
target.targets += $$QMAKE_TARGET_DEBUG_INFO
}
shell_target = $$shell_quote($$relative_path($$QMAKE_RESOLVED_TARGET, $$OUT_PWD))
shell_target_debug_info = $$shell_quote($$relative_path($$QMAKE_TARGET_DEBUG_INFO, $$OUT_PWD))
copy_debug_info = $$debug_info_copy_bin $$debug_info_keep $$shell_target $$debug_info_out $$shell_target_debug_info
strip_debug_info = $$debug_info_strip_bin $$debug_info_strip $$shell_target
!isEmpty(QMAKE_POST_LINK):QMAKE_POST_LINK = $$escape_expand(\\n\\t)$$QMAKE_POST_LINK
darwin {
mkdir_debug_info = $$QMAKE_MKDIR $$shell_quote($$debug_info_target_dir)
QMAKE_POST_LINK = $$mkdir_debug_info && $$copy_debug_info && $$strip_debug_info $$QMAKE_POST_LINK
} else {
link_debug_info = $$QMAKE_OBJCOPY --add-gnu-debuglink=$$shell_target_debug_info $$shell_target
!contains(QMAKE_HOST.os, Windows): \
QMAKE_POST_LINK = && chmod -x $$shell_target_debug_info $$QMAKE_POST_LINK
QMAKE_POST_LINK = $$copy_debug_info && $$strip_debug_info && $$link_debug_info $$QMAKE_POST_LINK
}
silent:QMAKE_POST_LINK = @echo creating $@.$$debug_info_suffix && $$QMAKE_POST_LINK
QMAKE_DISTCLEAN += $$QMAKE_TARGET_DEBUG_INFO
}

14
mkspecs/features/unix/thread.prf Normal file
View File

@ -0,0 +1,14 @@
!isEmpty(QMAKE_CFLAGS_THREAD) {
QMAKE_CFLAGS += $$QMAKE_CFLAGS_THREAD
QMAKE_EXPORT_CFLAGS += $$QMAKE_CFLAGS_THREAD
}
!isEmpty(QMAKE_CXXFLAGS_THREAD) {
QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_THREAD
QMAKE_EXPORT_CXXFLAGS += $$QMAKE_CXXFLAGS_THREAD
}
INCLUDEPATH += $$QMAKE_INCDIR_THREAD
LIBS += $$QMAKE_LIBS_THREAD
!isEmpty(QMAKE_LFLAGS_THREAD):QMAKE_LFLAGS += $$QMAKE_LFLAGS_THREAD
!isEmpty(QMAKE_CC_THREAD):QMAKE_CC = $$QMAKE_CC_THREAD
!isEmpty(QMAKE_CXX_THREAD):QMAKE_CXX = $$QMAKE_CXX_THREAD
!isEmpty(QMAKE_LINK_THREAD):QMAKE_LINK = $$QMAKE_LINK_THREAD

1
mkspecs/features/unix/x11.prf Normal file
View File

@ -0,0 +1 @@
CONFIG *= x11lib x11inc

3
mkspecs/features/unix/x11inc.prf Normal file
View File

@ -0,0 +1,3 @@
INCLUDEPATH += $$QMAKE_INCDIR_X11
QMAKE_CFLAGS += $$QMAKE_CFLAGS_X11
QMAKE_CXXFLAGS += $$QMAKE_CFLAGS_X11

2
mkspecs/features/unix/x11lib.prf Normal file
View File

@ -0,0 +1,2 @@
!isEmpty(QMAKE_LIBDIR_X11):QMAKE_LIBDIR += $$QMAKE_LIBDIR_X11
LIBS_PRIVATE += $$QMAKE_LIBS_X11

1
mkspecs/features/unix/x11sm.prf Normal file
View File

@ -0,0 +1 @@
!isEmpty(QMAKE_LIBDIR_X11):QMAKE_LIBDIR += $$QMAKE_LIBDIR_X11