qt 6.5.1 original

mkspecs/features/win32/console.prf

@@ -0,0 +1,5 @@
+CONFIG -= windows
+QMAKE_LFLAGS += $$QMAKE_LFLAGS_CONSOLE
+contains(TEMPLATE, ".*app") {
+    QMAKE_LFLAGS += $$QMAKE_LFLAGS_EXE
+}

mkspecs/features/win32/default_pre.prf

@@ -0,0 +1,2 @@
+CONFIG = windows $$CONFIG entrypoint
+load(default_pre)

mkspecs/features/win32/dumpcpp.prf

@@ -0,0 +1,36 @@
+qtPrepareTool(QMAKE_DUMPCPP, dumpcpp)
+
+dumpcpp_decl.depends += $$QMAKE_DUMPCPP_EXE
+dumpcpp_decl.commands = $$QMAKE_DUMPCPP ${QMAKE_FILE_IN} -o ${QMAKE_FILE_BASE}
+qaxcontainer_compat: dumpcpp_decl.commands += -compat
+dumpcpp_decl.output = ${QMAKE_FILE_BASE}.h
+dumpcpp_decl.input = TYPELIBS
+dumpcpp_decl.variable_out = HEADERS
+dumpcpp_decl.name = DUMP
+dumpcpp_decl.CONFIG += no_link
+
+QMAKE_EXTRA_COMPILERS += dumpcpp_decl
+
+
+dumpcpp_impl.commands = $$escape_expand(\\n)    # dummy command
+dumpcpp_impl.output = ${QMAKE_FILE_BASE}.cpp
+dumpcpp_impl.input = TYPELIBS
+dumpcpp_impl.variable_out = SOURCES
+dumpcpp_impl.name = CPP
+dumpcpp_impl.depends += ${QMAKE_FILE_BASE}.h
+
+QMAKE_EXTRA_COMPILERS += dumpcpp_impl
+
+
+# Call dumpcpp the first time if the files do not exist to help find dependencies
+!build_pass:have_target:!contains(TEMPLATE, vc.*) {
+    for(tlb, TYPELIBS) {
+        tlbCopy = $$replace(tlb, \", )
+        hdr = $$basename(tlbCopy)
+        hdr = $$section(hdr, ., 0, -2)
+        tmp_command = $$QMAKE_DUMPCPP $$system_quote($$absolute_path($$tlbCopy, $$_PRO_FILE_PWD_)) \
+                        -o $$system_quote($$OUT_PWD/$$hdr)
+        qaxcontainer_compat: tmp_command += -compat
+        !exists($$OUT_PWD/$${hdr}.h): system($$tmp_command)
+    }
+}

mkspecs/features/win32/idcidl.prf

@@ -0,0 +1,47 @@
+build_pass:console {
+    warning("QAxServer applications cannot be console applications.")
+    warning("Remove 'console' from your CONFIG.")
+}
+
+CONFIG -= entrypoint
+
+ACTIVEQT_VERSION = $$VERSION
+isEmpty(ACTIVEQT_VERSION):ACTIVEQT_VERSION = 1.0
+
+qtPrepareTool(QMAKE_IDC, idc)
+contains(TEMPLATE, "vc.*") {
+    ACTIVEQT_IDC = $${QMAKE_IDC}
+    ACTIVEQT_IDL = $${QMAKE_IDL}
+    ACTIVEQT_TARGET = \"$(TargetPath)\"
+    ACTIVEQT_NEWLINE = $$escape_expand(\\n\\t)
+    ACTIVEQT_OUTPUT = $(IntDir)$${TARGET}
+    ACTIVEQT_TLBOUT = \"$(TargetDir)/$${TARGET}.tlb\"
+    GENERATED += $${OBJECTS_DIR}/$${TARGET}.idl $${ACTIVEQT_TLBOUT}
+} else {
+    ACTIVEQT_IDC = -$(IDC)
+    ACTIVEQT_IDL = -$(IDL)
+    ACTIVEQT_NEWLINE = $$escape_expand(\\n\\t)
+    ACTIVEQT_TARGET = $(DESTDIR_TARGET)
+    ACTIVEQT_OUTPUT = $(OBJECTS_DIR)/$${TARGET}
+    isEmpty(DESTDIR) {
+        ACTIVEQT_TLBOUT = $${TARGET}.tlb
+    } else {
+        ACTIVEQT_TLBOUT = $${DESTDIR}/$${TARGET}.tlb
+    }
+}
+
+!qaxserver_no_postlink {
+    !isEmpty(QMAKE_POST_LINK):QMAKE_POST_LINK += $$quote($$ACTIVEQT_NEWLINE)
+    QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /idl $${ACTIVEQT_OUTPUT}.idl -version $${ACTIVEQT_VERSION}$${ACTIVEQT_NEWLINE})
+    !isEmpty(RC_FILE) {
+        QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDL "$${ACTIVEQT_OUTPUT}.idl" /nologo /tlb "$${ACTIVEQT_OUTPUT}.tlb"$$ACTIVEQT_NEWLINE)
+        QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /tlb $${ACTIVEQT_OUTPUT}.tlb$$ACTIVEQT_NEWLINE)
+    } else {
+        QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDL "$${ACTIVEQT_OUTPUT}.idl" /nologo /tlb "$${ACTIVEQT_TLBOUT}"$$ACTIVEQT_NEWLINE)
+        message("No rc-file linked into project; type library will be a separate file.")
+    }
+    !qaxserver_no_register: \
+        QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /regserver)
+    QMAKE_CLEAN += $${ACTIVEQT_OUTPUT}.idl $${ACTIVEQT_OUTPUT}.tlb
+}
+

mkspecs/features/win32/msvc_mp.prf

@@ -0,0 +1,2 @@
+QMAKE_CFLAGS += $$QMAKE_CFLAGS_MP
+QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_MP

mkspecs/features/win32/opengl.prf

@@ -0,0 +1,6 @@
+QT_FOR_CONFIG += gui
+
+!qtConfig(dynamicgl) {
+    QMAKE_LIBS += $$QMAKE_LIBS_OPENGL
+    QMAKE_LFLAGS += $$QMAKE_LFLAGS_OPENGL
+}

mkspecs/features/win32/separate_debug_info.prf

@@ -0,0 +1,22 @@
+have_target:!static:!isEmpty(QMAKE_OBJCOPY) {
+    load(resolve_target)
+    QMAKE_TARGET_DEBUG_INFO = $${QMAKE_RESOLVED_TARGET}.debug
+
+    shell_target = $$shell_quote($$relative_path($$QMAKE_RESOLVED_TARGET, $$OUT_PWD))
+    shell_target_debug_info = $$shell_quote($$relative_path($$QMAKE_TARGET_DEBUG_INFO, $$OUT_PWD))
+    copy_debug_info = $$QMAKE_OBJCOPY --only-keep-debug $$shell_target $$shell_target_debug_info
+    link_debug_info = $$QMAKE_OBJCOPY --add-gnu-debuglink=$$shell_target_debug_info $$shell_target
+    strip_debug_info = $$QMAKE_OBJCOPY --strip-debug $$shell_target
+
+    !isEmpty(QMAKE_POST_LINK):QMAKE_POST_LINK = $$escape_expand(\\n\\t)$$QMAKE_POST_LINK
+
+    QMAKE_POST_LINK = $$copy_debug_info && $$strip_debug_info && $$link_debug_info $$QMAKE_POST_LINK
+    silent:QMAKE_POST_LINK = @echo creating $@.debug && $$QMAKE_POST_LINK
+
+    contains(TEMPLATE, lib$):!plugin {
+        dlltarget.targets += $$QMAKE_TARGET_DEBUG_INFO
+    } else {
+        target.targets += $$QMAKE_TARGET_DEBUG_INFO
+    }
+    QMAKE_DISTCLEAN += $$QMAKE_TARGET_DEBUG_INFO
+}

mkspecs/features/win32/stl.prf

@@ -0,0 +1,3 @@
+CONFIG -= stl_off
+QMAKE_CFLAGS *= $$QMAKE_CFLAGS_STL_ON
+QMAKE_CXXFLAGS *= $$QMAKE_CXXFLAGS_STL_ON

mkspecs/features/win32/stl_off.prf

@@ -0,0 +1,3 @@
+CONFIG -= stl
+QMAKE_CFLAGS += $$QMAKE_CFLAGS_STL_OFF
+QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_STL_OFF

mkspecs/features/win32/windeployqt.prf

@@ -0,0 +1,19 @@
+# Extra target for running windeployqt
+qtPrepareTool(QMAKE_WINDEPLOYQT, windeployqt)
+build_pass {
+    load(resolve_target)
+
+    isEmpty(WINDEPLOYQT_OPTIONS): WINDEPLOYQT_OPTIONS = -qmldir $$shell_quote($$system_path($$_PRO_FILE_PWD_))
+    WINDEPLOYQT_TARGET = $$shell_quote($$system_path($$QMAKE_RESOLVED_TARGET))
+    WINDEPLOYQT_OUTPUT = $$shell_quote($$system_path($$dirname(QMAKE_RESOLVED_TARGET)/$$basename(TARGET).windeployqt))
+    windeployqt.target = windeployqt
+    windeployqt.commands = $$QMAKE_WINDEPLOYQT $$WINDEPLOYQT_OPTIONS -list target $$WINDEPLOYQT_TARGET > $$WINDEPLOYQT_OUTPUT
+
+    windeployqt_clean.commands = if exist $$WINDEPLOYQT_OUTPUT for /f %i in ($$WINDEPLOYQT_OUTPUT) do $$QMAKE_DEL_FILE %~fi && $$QMAKE_DEL_DIR %~pi
+    DISTCLEAN_DEPS += windeployqt_clean
+    QMAKE_DISTCLEAN += $$WINDEPLOYQT_OUTPUT
+} else {
+    windeployqt.CONFIG += recursive
+    windeployqt_clean.CONFIG += recursive
+}
+QMAKE_EXTRA_TARGETS += windeployqt windeployqt_clean

mkspecs/features/win32/windows.prf

@@ -0,0 +1,5 @@
+CONFIG -= console
+QMAKE_LFLAGS += $$QMAKE_LFLAGS_WINDOWS
+contains(TEMPLATE, ".*app") {
+    QMAKE_LFLAGS += $$QMAKE_LFLAGS_EXE
+}

mkspecs/features/win32/windows_vulkan_sdk.prf

@@ -0,0 +1,13 @@
+isEmpty(QMAKE_INCDIR_VULKAN) {
+    # Pick up the VULKAN_SDK env var set by the LunarG SDK so that the Vulkan
+    # headers are found out-of-the-box on typical Windows setups.
+    QMAKE_INCDIR_VULKAN = $$(VULKAN_SDK)/include
+
+    # Do not add default include paths as that can knock std headers
+    # out of their stride due to their usage of #include_next.
+    contains(QMAKE_DEFAULT_INCDIRS, $$re_escape($$QMAKE_INCDIR_VULKAN)): \
+        QMAKE_INCDIR_VULKAN =
+
+    # Do not export the include dir but resolve it on every qmake call.
+    QMAKE_EXPORT_INCDIR_VULKAN = -
+}